Лекция №1: Стандарты языка sql - polpoz.ru o_O
Главная
Поиск по ключевым словам:
Похожие работы
Название работы Кол-во страниц Размер
Лекция №6 Содержание лекции Методология и технология разработки информационных... 3 349.13kb.
Аналізуючих функцій 1 232.02kb.
Программа мероприятий в рамках проведения комплекса методических... 1 81.93kb.
Целью данной дисциплины является дать студентам представление о системах... 1 34.24kb.
Лекция по татарскому языку. Тема: «История народа в тюркских рунических... 1 41.57kb.
Tegova (European Group of Professional Valuers ) Утвержденные Европейские... 8 2401.83kb.
Проект стандарты управления рисками для негосударственных пенсионных... 22 1709.83kb.
Система образования статья 10 1 251.96kb.
Лекция №1 Типология языков как особый раздел языкознания 1 86.13kb.
Методы активного обучения на уроках английского языка Учитель английского... 1 62.78kb.
Статья «Международные стандарты по информационной безопасности» Вопрос... 1 37.5kb.
Обзор новой функциональности 1 316.53kb.
1. На доске выписаны n последовательных натуральных чисел 1 46.11kb.

Лекция №1: Стандарты языка sql - страница №12/13

Лекция №13: Объектно-ориентированное программирование в PL/SQL



Объектные типы
Объектным типом называется определяемый пользователем тип данных, который инкапсулирует структуру данных и подпрограммы.

Переменные, используемые в структуре данных объектного типа, называются атрибутами, или переменными объектного типа. Функции и процедуры, определяющие поведение объекта, называются методами.

При объявлении переменной объектного типа создается объект с атрибутами и методами, определяемым его типом.

Информация об объектном типе сохраняется в базе данных.

К преимуществам применения объектных типов можно отнести следующие их возможности:


  • использование объектных типов позволяет перемещать код управления данными из блоков PL/SQL в методы объекта с помощью инкапсуляции данных;

  • объектный тип ограничивает доступ к структуре объекта, предоставляя свои методы для работы с данными;

  • объектные типы хорошо реализуются классами объектно-ориентированных языков программирования.

Спецификация и тело объектного типа


Объектный тип состоит из двух частей: спецификации и тела.

Спецификация типа доступна в клиентском приложении. Тело типа скрыто, но разработчик существующего в базе данных типа имеет возможность изменять реализацию методов.

Спецификация типа создается оператором CREATE TYPE, который, с некоторыми сокращениями, может иметь следующее формальное описание:



CREATE [OR REPLACE] TYPE [schema .] type_name
{ { IS | AS } OBJECT }
[( { attribute datatype [sqlj_object_type_attr] } ]
   | { [ {[[[NOT] OVERRIDING] [[NOT] FINAL] [[NOT] INSTANTIABLE] ]
        { { MEMBER | STATIC } { procedure_spec | function_spec }|
     | {{ MAP | ORDER } MEMBER function_spec}} }]
     .,…}
  [[NOT] FINAL] [[NOT] INSTANTIABLE];

Определение функции (function_spec) указывается как:

FUNCTION name (parameter datatype .,…) { RETURN datatype }

Определение процедуры (procedure_spec) указывается как:



PROCEDURE name (parameter datatype .,…)

Тело типа создается оператором CREATE TYPE BODY, который, с некоторыми сокращениями, может иметь следующее формальное описание:

[CREATE TYPE BODY type_name {IS | AS}


     { {MAP | ORDER} MEMBER function_body;
     | MEMBER {procedure_body | function_body};}
     [MEMBER {procedure_body | function_body};]... END;]

Создание объектного типа выполняется в два этапа: сначала оператором CREATE TYPE создается спецификация типа, а затем оператором CREATE TYPE BODY создается- тело типа.

Например:

-- Создание объектного типа


CREATE TYPE MyT AS OBJECT (
   r1 REAL,   -- Атрибуты типа
   r2 REAL,
   MEMBER FUNCTION plus (x MyT) RETURN MyT
   );
CREATE TYPE BODY MyT AS
   MEMBER FUNCTION plus (x MyT) RETURN MyT IS
     BEGIN
         RETURN MyT (r1 + x.r1, r2 + x.r2);      END plus;
   END;
-- Применение переменной объектного типа:
DECLARE
   с1 MyT;   -- Создается объект с1 типа MyT
BEGIN
   с1 := MyT (1,1);   -- Вызов конструктора
END;

На атрибут объектного типа накладываются следующие ограничения:



  • типом атрибута может быть любой тип данных Oracle за исключением некоторых типов, включая типы LONG, LONG RAW, NCHAR, NCLOB, NVARCHAR2, ROWID, BOOLEAN, PLS_INTEGER, RECORD, REF CURSOR, %TYPE и %ROWTYPE, а также типы, определенные в пакете PL/SQL;

  • при объявлении атрибута его нельзя инициализировать, используя оператор присваивания или ключевое слово DEFAULT;

  • на атрибут не может быть наложено ограничение NOT NULL.

Типом атрибута может быть любой допустимый тип или другой объектный тип, называемый в этом случае вложенным объектным типом.

Объектные типы могут применяться при создании таблиц как типы полей.

Например:

CREATE TYPE typ1 AS OBJECT (a1 NUMBER,


   MEMBER FUNCTION getf1 RETURN NUMBER);
-- …
CREATE TABLE tbl1(col typ1);   -- Создание таблицы
-- …
SELECT col.getf1() FROM tbl1;   -- Вызов метода объектного типа

Спецификация объектного типа должна включать объявление каждого общедоступного метода, реализация которого записывается в теле объектного типа.

Перед названием метода объектного типа при спецификации объектного типа и описании тела этого типа всегда указывается ключевое слово MEMBER.

Для квалификации атрибутов в методах объектного типа можно использовать ключевое слово SELF, рассматриваемое как ссылка на данный объект. Однако синтаксис языка PL/SQL не требует обязательной квалификации атрибута. Параметр SELF может быть указан первым параметром функции и процедуры и явным способом. Если параметр SELF явно не указывается, то для функции предполагается определение параметра с опцией IN (входной параметр), а для процедуры - с опцией IN OUT (входной-выходной параметр).

Объектный тип может иметь перегружаемые методы.

Сравнение значений объектного типа


В отличие от значений скалярных типов для значений объектных типов не существует единого правила их сравнения. В языке PL/SQL определены ключевые слова MAP и ORDER, которые позволяют специфицировать метод, определяющий правила сравнения значений объектного типа. Объектный тип может иметь только один метод, выполняющий сравнение экземпляров данного типа, - MAP-метод или ORDER-метод.

В зависимости от значения объектного типа MAP-метод можно рассматривать как некоторую функцию хеширования.

ORDER-метод - это функция с двумя параметрами (первый из которых является встроенным по умолчанию), возвращающая значение скалярного типа (DATE, NUMBER, VARCHAR2, CHARACTER или REAL), получаемое при сравнении первого параметра, всегда равного SELF, со вторым параметром, указывающем объект этого же типа.

В SQL-операторах всегда можно сравнивать два значения объектного типа на эквивалентность - полное совпадение значений всех атрибутов, но выполнять сравнение на упорядочивание можно только в том случае, если объектный тип имеет MAP-метод или ORDER-метод.


Конструкторы объектного типа


Oracle по умолчанию для каждого объектного типа создает конструктор, одноименный с названием типа.

Конструктор используется для инициализации и возвращения экземпляра объектного типа. При инициализации объекта вызывается конструктор со списком параметров, которые определяют атрибуты в порядке их объявления.




Пакеты языка PL/SQL

Создание пакета


Пакет - это объект схемы, который объединяет логически зависимые типы PL/SQL, данные и подпрограммы. Пакет состоит из двух частей: спецификации пакета и тела пакета.

В спецификации пакета объявляются доступные типы, переменные, константы, исключения, курсоры и подпрограммы.

В теле пакета содержится определение курсоров и реализация подпрограмм. Все элементы, объявляемые в теле пакета, невидимы для приложения, что позволяет скрывать от пользователя детали реализации подпрограмм.

Определение спецификации пакета выполняется оператором CREATE PACKAGE, который может иметь следующее формальное описание:

CREATE PACKAGE name AS -- Спецификация (видимая часть)
     -- Объявление общедоступных типов и переменных
     -- Спецификация подпрограмм
END [name];

Определение тела пакета выполняется оператором CREATE PACKAGE BODY, который может иметь, с некоторыми сокращениями, следующее формальное описание:

CREATE PACKAGE BODY name AS -- Тело пакета (скрытая часть)
     -- Объявление локальных типов и переменных
     -- Тела подпрограмм
END [name];

Например:

CREATE PACKAGE tbl_rows AS   -- Спецификация пакета
   TYPE RecTBL1 IS RECORD (tbl1f1 INTEGER, tbl1f2 REAL);
   PROCEDURE insert_tbl1 (f1 INTEGER, f2 REAL);
END tbl_rows;

CREATE PACKAGE BODY tbl_rows AS   -- Тело пакета


   PROCEDURE insert_tbl1 (f1 INTEGER, f2 REAL) IS
   BEGIN
      INSERT INTO tbl1 VALUES (f1,f2);
   END insert_tbl;
END tbl_rows;

На общедоступные элементы пакета - типы, переменные и методы, можно ссылаться из триггеров, хранимых подпрограмм или OCI-приложений, используя следующий синтаксис: package_name.item_name.

Вызов пакетной процедуры из встроенного SQL может быть реализован в анонимом блоке PL/SQL, для выполнения которого используется SQL-оператор EXECUTE.

Например:

EXEC SQL EXECUTE BEGIN tbl_rows.insert_tbl1(1, 200); END;

Подпрограммы


Подпрограммами называются именованные блоки PL/SQL, которые могут иметь параметры.

Язык PL/SQL позволяет создавать подпрограммы и как процедуры, так и как функции PL/SQL.

Подпрограммы могут быть объявлены в любом блоке PL/SQL, подпрограмме или пакете. Любая процедура или функция должна быть объявлена до ее использования. В том случае, если одной подпрограмме требуется использовать другую подпрограмму, объявляемую позже, то следует использовать механизм предварительного объявления. При этом предварительно объявляемая подпрограмма содержит только спецификацию, а полное объявление подпрограммы может быть выполнено ниже в соответствии с обычным синтаксисом.

Для того чтобы подпрограмму пакета можно было вызвать извне, она должна быть объявлена в спецификации пакета, определяемой оператором CREATE PACKAGE.

Для того чтобы самостоятельную подпрограмму можно было вызвать извне она должна храниться в базе данных. Такие подпрограммы называются хранимыми процедурами или хранимыми функциями. Для их создания применяются SQL-операторы CREATE PROCEDURE и CREATE FUNCTION.

Определение процедуры может иметь следующее формальное описание:



PROCEDURE name [(parameter[, parameter, ...])]
IS
       [local declarations]
   BEGIN
     executable statements
   [EXCEPTION
     exception handlers]
END [name];

Параметры в списке параметров определяются как:

parameter_name [IN | OUT | IN OUT] datatype
                         [{:= | DEFAULT} expression]

Параметры, используемые при объявлении процедуры или функции, называются формальными параметрами, а при вызове - фактическими параметрами.

Язык PL/SQL позволяет, чтобы количество фактических параметров было меньше, чем количество формальных параметров. В этом случае будут использованы значения по умолчанию, которые обязательно должны присутствовать для отсутствующих значений параметров.

Для определения соответствия между формальными и фактическими параметрами предусмотрены два типа нотаций:



  • позиционная;

  • именованная.

При позиционной нотации порядок формальных и фактических параметров должен совпадать.

При именованной нотации порядок указания параметров не имеет значения, но перед значением параметра указывается имя формального параметра и символ =>. Список параметров может содержать оба типа нотаций одновременно, но именованная нотация располагается только в конце списка.

Процедура имеет две части:


  • спецификацию, начинающуюся ключевым словом PROCEDURE и завершающуюся именем процедуры или списком параметров;

  • тело процедуры, начинающееся ключевым словом IS и завершающееся ключевым словом END.

Тело процедуры, как и любой блок PL/SQL, имеет секцию объявлений, секцию выполняемого кода и необязательную секцию обработчиков исключений.

Определение функции может иметь следующее формальное описание:



FUNCTION name [(parameter[, parameter, ...])] RETURN datatype
IS
   [local declarations]
BEGIN
   executable statements
[EXCEPTION
   exception handlers]
END [name];

Параметры в списке параметров определяются как:

parameter_name [IN | OUT | IN OUT] datatype
                         [{:= | DEFAULT} expression]

Например:



FUNCTION fun1 (f1 REAL, f2 REAL) RETURN BOOLEAN IS
   min_f1 REAL :=0;
   max_f1 REAL :=1;
BEGIN
   SELECT ff1min, ff2max INTO min_f1, max_f1 FROM tbl1
      WHERE ff2 = f2;
   RETURN (f1 >= min_f1) AND (f2 <= max_f1);
EXCEPTION
   WHEN NO_DATA_FOUND THEN
      INSERT INTO tbl2 VALUES (min_f1, max_f1);
      RETURN FALSE;
END fun1;

Язык PL/SQL позволяет создавать перегружаемые подпрограммы, имеющие одинаковое имя, но различный список формальных параметров. Параметры перегружаемых функций должны различаться хотя бы по одному из следующих признаков: по типу, по количеству, по порядку следования параметров.



Перегружаемые подпрограммы можно применять для реализации одних и тех же действий над переменными различных типов. Для перегружаемых подпрограмм компилятор будет искать подпрограмму с совпадающим списком фактических параметров только до тех пор, пока не просмотрит все перегружаемые подпрограммы данного блока. И только в том случае, если перегружаемых подпрограмм с указанным именем в данном блоке нет, то компилятор продолжит поиск во внешнем блоке.

Рекурсивные и взаимно рекурсивные вызовы подпрограмм


Рекурсивным вызовом называется вызов подпрограммы из тела этой же подпрограммы.

При каждом рекурсивном вызове:



  • создается новый экземпляр всех элементов, объявленных в подпрограмме, включая параметры, переменные, курсоры и исключения;

  • создается свой экземпляр SQL-оператора.

Рассмотрим в качестве примера рекурсивных вызовов создание последовательности Фибоначчи (1, 1, 2, 3, 5, 8, 13, 21, ...), в которой каждый следующий элемент является суммой двух предыдущих.

Следующая функция fibonati1 реализует формирование последовательности Фибоначчи с применением рекурсии:

FUNCTION fibonati1 (n POSITIVE) RETURN INTEGER IS
BEGIN
   IF (n = 1) OR (n = 2) THEN
    RETURN 1;
   ELSE
    RETURN fibonati1 (n-1) + fibonati1 (n-2);
   END IF;
END fibonati1;

Вместо рекурсивного способа можно использовать и итерационный способ, который менее нагляден, но требует и меньше памяти и быстрее выполняется.

Так, следующая функция fibonati2 реализует формирование последовательности Фибоначчи итерационным способом:

FUNCTION fibonati2 (n POSITIVE) RETURN INTEGER IS


   pos1 INTEGER := 1;
   pos2 INTEGER := 0;
   sum INTEGER;
BEGIN
   IF (n = 1) OR (n = 2) THEN
      RETURN 1;
   ELSE
      sum := pos1 + pos2;
      FOR i IN 3..n LOOP
         pos2 := pos1;
         pos1 := sum;
         sum := pos1 + pos2;
      END LOOP;
      RETURN sum;
   END IF;
END fibonati2;

Язык PL/SQL позволяет реализовывать взаимно рекурсивные вызовы, при которых подпрограммы прямо или опосредованно вызывают друг друга.



Внешние процедуры


Использование внешних процедур значительно расширяет функциональность сервера, предоставляя интерфейс для вызова программ, разработанных на других языках программирования, таких как C++ или Pascal, и созданных как DLL-библиотеки.

Во время выполнения блока PL/SQL динамически загружается DLL-библиотека и происходит вызов внешней процедуры как подпрограммы PL/SQL. Внешние процедуры всегда выполняются в отдельном процессе.

Вызовы внешних процедур можно выполнять из:


  • анонимных блоков PL/SQL;

  • методов, объявленных в объектном типе;

  • хранимых или пакетных подпрограмм;

  • триггеров базы данных;

  • SQL-операторов, вызываемых только для пакетных подпрограмм.

Для применения внешней процедуры следует сначала определить используемую DLL-библиотеку, выполнив оператор CREATE LIBRARY library_name {IS | AS} 'file_path';. Затем необходимо зарегистрировать внешнюю процедуру, указав в процедуре PL/SQL, используемой для опосредованного вызова внешней процедуры, место расположения процедуры, способ ее вызова и список передаваемых параметров.

Если DLL-библиотека c_lib.dll содержит функцию f1_ext, которая определена в С как int c_ext_f1(int x_val, int y_val);, то подпрограмма PL/SQL reg_ext_f1, выполняющая регистрацию этой внешней процедуры, может быть записана следующим образом:



CREATE FUNCTION reg_ext_f1(
   x BINARY_INTEGER, y BINARY_INTEGER)
   RETURN BINARY_INTEGER AS EXTERNAL
   LIBRARY c_lib
   NAME "c_ext_f1"   -- Имя внешней функции
   LANGUAGE C;

Для вызова внешней функции DLL-библиотеки из анонимного блока PL/SQL достаточно выполнить вызов функции PL/SQL, зарегистрированной как внешняя функция.

Например:

DECLARE
   var1 BINARY_INTEGER;
   x BINARY_INTEGER;
   y BINARY_INTEGER;
BEGIN
x:=1; y:=2;
-- Вызов внешней функции f1_ext:
   var1 := reg_ext_f1(x, y);
END;






<< предыдущая страница   следующая страница >>


izumzum.ru